Clase ParsearURL

Jul 31

ParsearURL, es una clase la cual sirve para buscar en un texto direcciones http o ftp (Por ejemplo http://misitio.com) y agregarle o quitarle la etiqueta de vínculo <a>. (Siendo el resultado obtenido: <a href='http://misitio.com'>http://misitio.com</a>)

Paquete: as3.toronana.cadenas
Clase: public final class ParsearURL
Herencia: no posee
Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

La clase ParsearURL contiene 2 métodos estáticos y deben llamarse utilizando la sintaxis ParsearURL.metodo(parametros).

Métodos Públicos

  • textoToVinculo(texto:String, tagExtra:String="u"):String
    [static] Busca en el texto direcciones http y ftp y devuelve todo el texto con las direcciones vinculadas con la etiqueta<a>

      Parámetros:

    1. texto:String - Texto donde se buscarán las direcciones http:// y ftp://
    2. tagExtra:String - Etiqueta html extra para agregar a las direcciones encontradas. (Por defecto es "u")
  • vinculoToTexto(texto:String, tagExtra:String="u"):String
    [static] Busca en el texto vínculos http y ftp y devuelve todo el texto en forma plana.

      Parámetros:

    1. texto:String - Texto donde se buscarán los vínculos http:// y ftp://
    2. tagExtra:String - Etiqueta html extra para quitar a los vínculos encontrados. (Por defecto es "u")

    • ver Texto Plano
    Actionscript:
    1. package as3.toronana.cadenas {
    2.    
    3.     /**
    4.     * @author Damián Musumeci - http://as.toronana.com.ar/
    5.     * @version 1.0
    6.     */ 
    7.     public final class ParsearURL   {
    8.        
    9.         /**
    10.         * Convertir direcciones HTTP y FTP a vínculos.
    11.         * @param texto, Texto plano donde se encuentra las direcciones HTTP o FTP a convertir a vínculos
    12.         * @param tagExtra, agregar una etiqueta extra. Por defecto utiliza u (subrayado). Dejar la cadena vacia para nada.
    13.         * @return String. Devuelve el texto completo, con las direcciones HTTP o FTP con los tag de vínculo
    14.         */
    15.         public static function textoToVinculo(texto:String,tagExtra:String="u"):String {           
    16.            
    17.             var protocolo:String = "((?:http|ftp)://)";      
    18.             var parteURL:String = "([./?=&a-z0-9_-]*)";
    19.             var protocoloWWW:String = "( www)";
    20.             var patron1:String = "<a href='$1$2'>$1$2</a>";
    21.             var patron2:String = "<a href='http://www$2'>www$2</a>";
    22.            
    23.             if (tagExtra != "") {
    24.                 patron1 = "<" + tagExtra + ">" + patron1 + "</" + tagExtra + ">";
    25.                 patron2 = "<" + tagExtra + ">" + patron2 + "</" + tagExtra + ">";
    26.             }
    27.            
    28.             var urlPattern:RegExp = new RegExp (protocolo + parteURL, "ig");
    29.             var resultado:String = texto.replace(urlPattern, patron1);
    30.             var urlPattern2:RegExp = new RegExp (protocoloWWW + parteURL, "ig");           
    31.             var resultado2:String = resultado.replace(urlPattern2, " "+patron2);
    32.            
    33.             return resultado2;
    34.         }
    35.        
    36.         /**
    37.         * Convertir vinculos HTTP y FTP en texto plano.
    38.         * @param texto Texto plano, donde se encuentra las direcciones HTTP o FTP a convertir a vínculos
    39.         * @param tagExtra, eliminar una etiqueta extra. Por defecto utiliza u (subrayado). Dejar la cadena vacia para nada.
    40.         * @return String. Devuelve el texto completo, con las direcciones HTTP o FTP con los tag de vínculo
    41.         */
    42.         public static function vinculoToTexto(texto:String, tagExtra:String = "u"):String {
    43.            
    44.             var protocolo:String = "((?:http|ftp)://)";      
    45.             var parteURL:String = "([./?=&a-z0-9_-]*)";
    46.             var expresion:String = "<a href='" + protocolo + parteURL + "'>" + protocolo + parteURL + "<\/a>";
    47.             var expresion2:String = "<a href='" + protocolo + parteURL + "'>" + parteURL + "<\/a>";
    48.            
    49.             if (tagExtra != "") {
    50.                 expresion = "<" + tagExtra + ">" + expresion + "</" + tagExtra + ">";
    51.                 expresion2 = "<" + tagExtra + ">" + expresion2 + "<\/" + tagExtra + ">";
    52.             }         
    53.            
    54.             var patron:RegExp = new RegExp (expresion, "ig");
    55.             var resultado:String = texto.replace(patron, "$1$2");         
    56.             var patron2:RegExp = new RegExp (expresion2, "ig");
    57.             var resultado2:String = resultado.replace(patron2, "$2");
    58.            
    59.             return resultado2;
    60.         }
    61.     }
    62. }

    Aquí les dejo un ejemplo de implementación y la clase.
    Descargar ParsearURL Version 1 Descargar: ParsearURL
    Descargado 330 veces


    Para mas detalles, pueden consultar la documentación aquí

    AS3, Clases
    ¿Te sirvió esta información?
    Contribuye para que este sitio siga existiendo.

    ____________________

    Publique su comentario