Clase CargarTexto

Ago 02

La clase CargarTexto, como el nombre dice, sirve para cargar una archivo de texto. Ahora también puede ser utilizada para cargar un xml, un jSon, un HTML o cualquier archivo que sea de texto. Esta clase viene acompañada con la clase EventCargarTexto. La cual maneja los eventos de Carga Completa y algunos errores que puedan surgir.

Paquete: as3.toronana.cadenas
Clase: public class CargarTexto
Herencia: URLLoader
Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Métodos Públicos

  • addVariable(nombreVariable:String, valor:String):void
    Agrega una variable y su valor para enviar.

    1. nombreVariable:String - Nombre de la variable que se enviará
    2. valor:String - Valor asignado a la variable a enviar
  • cargar(url:String, metodo:String = "POST"):void
    Envía variables en el caso que existan y carga el texto dado por el parametro url.

    1. url:String - Dirección absoluta o relativa donde se encuentra el archivo a cargar
    2. metodo:String - Método por el cual se enviarán las variables en caso de existir. (Por defecto POST. Se aconseja utilizar las constantes GET y POST de la clase URLRequestMethod)

    • ver Texto Plano
    Actionscript:
    1. package as3.toronana.cadenas {
    2.    
    3.     import flash.net.URLRequest;
    4.     import flash.net.URLLoader;
    5.     import flash.net.URLVariables;
    6.     import flash.events.Event;
    7.     import flash.events.IOErrorEvent;
    8.    
    9.     /**
    10.     * Clase CargarTexto. Carga un texto dado por una ruta absoluta o relativa. Si es necesari se pueden enviar variables
    11.     * ya sea en el método POST o GET.
    12.     * @author Damian Musumeci | http://as.toronana.com.ar/
    13.     * @version 1.0
    14.     * @see http://as.toronana.com.ar/186-clase-cargartexto/
    15.     */
    16.     public class CargarTexto extends URLLoader {       
    17.        
    18.         private var evento:EventCargarTexto;
    19.         private var variables:URLVariables;
    20.         private var requerimiento:URLRequest;
    21.        
    22.         private const ERROR_DE_SEGURIDAD:String = "Ha ocurrido un error de Seguridad. Es probable que exista una infracción en el entorno limitado de seguridad.";
    23.         private const ERROR_DE_ARGUMENTO:String = "Ha ocurrido un error de Argumento. Es posible que la cantidad de argumentos no coincidan.";
    24.         private const ERROR_DE_RUTA:String = "No se encuentra el archivo a cargar. Verifique la ruta, o bien su conexión a Internet.";
    25.        
    26.         public function CargarTexto() {
    27.             super();
    28.             this.variables = new URLVariables();
    29.         }
    30.        
    31.         /**
    32.         * Envía variables en el caso que existan y carga el texto dado por el parametro url.
    33.         * @param url Dirección relativa o absoluta donde se encuentra el archivo a cargar.
    34.         * @param metodo Metodo utilizado para el envío de variables, en el caso que existan. (Por defecto "POST")
    35.         * @return void
    36.         */
    37.         public function cargar(url:String, metodo:String = "POST" ):void {
    38.             this.requerimiento = new URLRequest();
    39.             this.requerimiento.url = url;
    40.             this.requerimiento.method = metodo;
    41.             this.requerimiento.data = this.variables;                  
    42.             this.addEventListener(Event.COMPLETE, onComplete);     
    43.             try {
    44.                 this.load(this.requerimiento);
    45.             } catch (error:ArgumentError){
    46.                 despacharError(error.message + ", " + this.ERROR_DE_ARGUMENTO);  
    47.             } catch (error:SecurityError) {
    48.                 despacharError(error.message + ", " + this.ERROR_DE_SEGURIDAD);  
    49.             }
    50.             this.addEventListener(IOErrorEvent.IO_ERROR, this.onIOERROR);
    51.         }
    52.        
    53.         /**
    54.         * Agrega una variable y su valor para enviar.
    55.         * @param nombreVariable Nombre de la variable a enviar.
    56.         * @param valor Valor de la variable a enviar.
    57.         * @return void
    58.         */
    59.         public function addVariable(nombreVariable:String, valor:String):void {
    60.             this.variables[nombreVariable] = valor;
    61.         }
    62.        
    63.         private function onComplete(e:Event):void {   
    64.             this.evento = new EventCargarTexto(EventCargarTexto.CARGAR_TEXTO_COMPLETADO, e.target.data);
    65.             this.dispatchEvent(this.evento);
    66.         }
    67.        
    68.         private function onIOERROR(e:IOErrorEvent):void {
    69.             despacharError(e.text + ", " + this.ERROR_DE_RUTA); 
    70.         }
    71.        
    72.         private function despacharError(error:String):void {
    73.             this.evento = new EventCargarTexto(EventCargarTexto.CARGAR_TEXTO_ERROR, error);
    74.             this.dispatchEvent(this.evento);
    75.         }      
    76.     }   
    77. }

    Paquete: as3.toronana.cadenas
    Clase: public class EventCargarTexto
    Herencia: Event
    Versión del lenguaje: ActionScript 3.0
    Versión del reproductor: Flash Player 9

    Constantes Públicas

  • CARGAR_TEXTO_COMPLETADO : String = "CARGAR_TEXTO_COMPLETADO"
    [static] Constante estática utilizada para captar cuando se ha completado de cargar el texto.
  • CARGAR_TEXTO_ERROR : String = "CARGAR_TEXTO_ERROR"
    [static] Constante estática utilizada para captar error al intentar cargar el texto.

    • Variables Públicas

  • texto:String. Esta variable recibe el texto cargado o bien una descripción del error ocurrido.
    • ver Texto Plano
    Actionscript:
    1. package as3.toronana.cadenas {
    2.    
    3.     import flash.events.Event;
    4.    
    5.     /**
    6.     * Clase EventCargarTexto. Evento propio de la clase CargarTexto.
    7.     * @author Damian Musumeci | http://as.toronana.com.ar/
    8.     * @version 1.0
    9.     * @see http://as.toronana.com.ar/186-clase-cargartexto/
    10.     */
    11.     public class EventCargarTexto extends Event {
    12.        
    13.         /** Variable pública, esta recibira el texto cargado o bien una descripción del error en el caso de ocurrirse. */
    14.         public var texto:String;
    15.         /** Constante estática utilizada para captar cuando se ha completado de cargar el texto. */
    16.         public static const CARGAR_TEXTO_COMPLETADO:String = "CARGAR_TEXTO_COMPLETADO";
    17.         /** Constante estática utilizada para captar error al intentar cargar el texto. */
    18.         public static const CARGAR_TEXTO_ERROR:String = "CARGAR_TEXTO_ERROR";
    19.        
    20.         public function EventCargarTexto(type:String, texto:String, bubbles:Boolean=false, cancelable:Boolean=false) {
    21.             this.texto = texto;
    22.             super(type, bubbles, cancelable);         
    23.         }
    24.        
    25.         public override function clone():Event {
    26.             return new EventCargarTexto(type, texto, bubbles, cancelable);
    27.         }
    28.        
    29.         public override function toString():String {
    30.             return formatToString("EventCargarTexto", "type", "texto", "bubbles", "cancelable", "eventPhase");
    31.         }      
    32.     }   
    33. }

    Aquí les dejo las clases y un ejemplo de implementación:
    Descargar CargarTexto Version 1 Descargar: CargarTexto
    Descargado 199 veces

    Para mas detalles, pueden consultar la documentación de la misma aqui

    AS3, Clases
    ¿Te sirvió esta información?
    Contribuye para que este sitio siga existiendo.

    ____________________

    Publique su comentario